Archief - Q: AS: Movieclip smooth verschuiven met AS

Rimpel · 31 mrt 2005

'll ik zou doormiddel van twee buttons (links en rechts) m'n MC willen laten verschuiven. Maar dit zou smooth moeten verlopen (nie direct verspringen maar alla motion tween) en er zou ook een max x waarde moeten zijn doordat hij niet buiten scherm kan doorschuiven.

ik heb nu op m'n buttons
on(release){
foto._x -=300
}
(hij moet verschuiven per 300px, de mc heet dus "foto")
maar hiermee verspringt hij uiteraard gewoon 300 px en hij zou moeten "schuiven".

kan iemand me hiermee helpen ?

=(X)=RaVen= · 31 mrt 2005

interval enzo
ge maakt een functie, verschuif
en die roep je met een interval aan, na 300px stop je met een if ofzo

Bigbuddha · 31 mrt 2005

What you need is easing

easing basics ->
http://www.actionscripts.org/tutorials/intermediate/Tweening/index4.shtml

manson · 31 mrt 2005

=(X)=RaVen= zei:
interval enzo
ge maakt een functie, verschuif
en die roep je met een interval aan, na 300px stop je met een if ofzo

en dat ... noemen ze de dingen moeilijk maken!

heel basis. dit plaats je in een frame op je tijdslijn (en niet rechtstreeks op je knop)

Code:

beweegMC = function(mc:String, naarWaar:Number, speed:Number){
	this[mc].onEnterFrame = function(){
		var difX = naarWaar - this._x;
		this._x -= difX/speed;
		if(Math.abs(difX) < 1){
			this._x = naarWaar;
			delete this.onEnterFrame;
		}
		
	}
}

this.button_btn.onRelease = function(){
	this._parent.beweegMC("mc", 300, 10);
}

Col.Kurtz · 31 mrt 2005

Met setInterval haal je veel mooier resultaat !

ziehier een voorbeeld van onEnterframe <> setInterval :
http://www.ifc-crew.com/slideTo/

Voor beide werd 5 als speed genomen

De twee prototypes :

Code:

MovieClip.prototype.slideTo = function(x, y, speed) {
	//
	this.onEnterFrame = function() {
		if (Math.abs((x-this._x))<1 && Math.abs((y-this._y))<1) {
			this._x = x;
			this._y = y;
			delete this.onEnterFrame;
		} else {
			this._x -= (this._x-x)/speed;
			this._y -= (this._y-y)/speed;
			updateAfterEvent();
		}
	};
};

Code:

MovieClip.prototype.slideTo = function(x, y, speed) {
	//
	this._x -= (this._x-x)/speed;
	this._y -= (this._y-y)/speed;
	//
	clearInterval(this.intervalId);
	//
	if (Math.abs((x-this._x))<1 && Math.abs((y-this._y))<1) {
		this._x = x;
		this._y = y;
	} else {
		this.intervalId = setInterval(this, "slideTo", 15, x, y, speed);
	}
	//
	updateAfterEvent();
};

The Patriot · 31 mrt 2005

PFft, hunder maakt da allemaal veel te moeilijk.

Moet eens zoeken achter dyntweens...

manson · 1 apr 2005

de slideTo van Kurtz is een goeie oplossing, mooi verpakt in een prototype
komt daar nog eens bij dat ik het niet wist van setInterval zijnde 'vlotter' dan onEnterFrame

LunchBox · 1 apr 2005

robert penner's easing equations:
http://www.robertpenner.com/easing/

> voor de demo(nstratie): selecteer een 'equation' en click ergens op het blauwe gedeelte +5cm van de bal, de curve is dus geen path maar het functievoorschrift in grafiek-vorm. (versnelling/vertraging)

> zo kan je relatief eenvoudig een elastisch effect nabootsen en zoveel meer, zeker'ns bekijken.

ps: macromedia heeft die zaken geïntegreerd in mx 2004 als'k me ni vergis.

Bigbuddha · 1 apr 2005

en om't jullie allemaal super makkelijk te maken.

-> http://laco.wz.cz/tween/

manson · 1 apr 2005

LunchBox zei:
ps: macromedia heeft die zaken geïntegreerd in mx 2004 als'k me ni vergis.

u vergist zich niet
zo te gebruiken:

Code:

new mx.transitions.Tween(mc, "_x", mx.transitions.easing.Elastic.easeInOut, begin, doel, tijd);

Archief - Q: AS: Movieclip smooth verschuiven met AS

Rimpel

Legacy Member

=(X)=RaVen=

Legacy Member

Bigbuddha

Legacy Member

manson

Legacy Member

Col.Kurtz

Legacy Member

The Patriot

Legacy Member

manson

Legacy Member

LunchBox

Legacy Member

Bigbuddha

Legacy Member

manson

Legacy Member