Archief - Extern tekstbestand inladen en weergeven

import flash.display.StageScaleMode;
import flash.display.StageAlign;
import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.events.Event;
import flash.utils.Timer;
import flash.events.TimerEvent;

stage.scaleMode = StageScaleMode.NO_SCALE;
stage.align = StageAlign.TOP_LEFT;

var bannerLoader:URLLoader;
var bannersArr:Array;
var timer:Timer;
var currentBanner:uint;

init();

//banners inladen
function init():void {
    bannerLoader = new URLLoader();
    var r:URLRequest = new URLRequest("banners.xml");
    bannerLoader.addEventListener(Event.COMPLETE, onBannersLoadComplete );
    bannerLoader.load(r);
}

//banners zijn ingeladen, hier voegen we ze per banner toe aan een array
function onBannersLoadComplete(e:Event):void {
    var banners:XML = XML(bannerLoader.data);
    bannersArr = new Array();
    
    for each(var banner:XML in banners.children()) {
        bannersArr.push(banner);
    }
    
    //Beginnen bij index 0 van de array en elke 2 seconden naar de volgende gaan
    currentBanner = 0;
    timer = new Timer(2000);
    timer.addEventListener(TimerEvent.TIMER, rotate);
    timer.start();
    
    rotate();
}

//Volgende waarde uit de array in het tekstvak zetten
function rotate(e:TimerEvent = null):void {
    //als we op het einde zitten moeten we terug bij index 0 beginnen.
    if(currentBanner == bannersArr.length) currentBanner = 0;
    txtBanners.text = bannersArr[currentBanner];
    currentBanner++;
}

<banners>
    <banner>banner 1</banner>
    <banner>banner 2</banner>
    <banner>banner 3</banner>
</banners>