Archief - ASP.NET: Bestanden/Directory openen (client side)

Rvl zei:

als ge naar een map wilt verwijzen op de server is het ook niet clientside maar serverside e. Dit kan je dan toch zeer gemakkelijk doen, een lijst van de bestanden in een dir bekomen

Klik om te vergroten...

dJeez zei:

Of het online zal werken heb ik zo mijn twijfels over, maar de URL moet dan de volgende vorm hebben : file://///pcnaam/sharenaam/

Klik om te vergroten...

Obliv` zei:

Kheb even geleden zowat een klein scriptje geschreven om de inhoud van een bepaalde dir op de server te listen.

index.asp

Code:

<script language="javascript" type="text/javascript">
function showFolder(objFolder)
{
	if (document.getElementById(objFolder).style.display == "none") 
	{
		document.getElementById(objFolder).style.display = "block";
	}
	else
	{
		document.getElementById(objFolder).style.display = "none";
	}
}
</script>

<%
	Dim intFolderID
	
	Function GetUrl(strPath)
		Dim strUrl
		
		strUrl = Right(strPath, Len(strPath) - Len(Server.MapPath("/")))
		strUrl = Replace(strUrl, "\", "/")
		
		GetUrl = strUrl
	End function
	
	Sub ListFolder(objFolder)
		Response.Write("<b>" & objFolder.Name & "</b>")
		Response.Write("<ul>")
		Response.Write("<li>Subfolders: " & objFolder.SubFolders.Count & "</li>")
		Response.Write("<li>Files: " & objFolder.Files.Count & "</li>")
		Response.Write("<li>Total size: " & Round((objFolder.Size / 1024), 2) & " kilobytes</li>")
		Response.Write("</ul>")
	End Sub
	
	Sub ListSubFolders(objFolder)
		Dim objSubFolder
		
		For Each objSubFolder in objFolder.SubFolders
			intFolderID = intFolderID + 1
			
			Response.Write("<li><a href=""javascript: showFolder('" & intFolderID & "');"">" & objSubFolder.Name & "</a> - " & Round((objSubFolder.Size / 1024), 2) & " kilobytes</li>")
			
			Response.Write("<ul id=""" & intFolderID & """ style=""display: none;"">")
			ListSubFolders(objSubFolder)
			ListFiles(objSubFolder)
			Response.Write("</ul>")
		Next
		
		Set objSubFolder = Nothing
	End Sub
	
	Sub ListFiles(objFolder)
		Dim objFile
		
		For Each objFile In objFolder.Files
			Response.Write("<li><a href=""" & GetURL(objFile.Path) & """>" & objFile.Name & "</a> - " & Round((objFile.Size / 1024), 2) & " kilobytes</li>")
		Next
		
		Set objFile = Nothing
	End Sub
	
	Sub ListFolderContents(strPath)
		Dim objFso, objFolder
		
		Set objFso = CreateObject("Scripting.FileSystemObject")
		Set objFolder = objFso.GetFolder(strPath)
		
		ListFolder(objFolder)
		
		Response.Write("<b>Content</b>")
		Response.Write("<ul>")
		
		ListSubFolders(objFolder)
		ListFiles(objFolder)
		
		Response.Write("</ul>")
		
		Set objFolder = Nothing
		Set objFso = Nothing
	End Sub

	ListFolderContents(Request.QueryString("txtPath")) 
%>

sla deze code op als index.asp. Upload het naar je server. Surf dan naar die pagina met als parameter de dir die je wilt bekijken. dus http://www.host.com/index.asp?txtPath=c:/temp/ ofzo

Klik om te vergroten...

 This type of page is not served.
Description: The type of page you have requested is not served because it has been explicitly forbidden.  The extension '.asp' may be incorrect.   Please review the URL below and make sure that it is spelled correctly.

Requested URL: /Tailored Blank/browsedir.asp

orez zei:

verander de extensie dan naar browserdir.aspX hé...

Klik om te vergroten...

NoFate zei:

Hey

Zou je dit scriptje ook in aspx formaat kunnen schrijven?
Ik ben dit aan het testen in .NET development server en ik krijg deze error :

Code:

 This type of page is not served.
Description: The type of page you have requested is not served because it has been explicitly forbidden.  The extension '.asp' may be incorrect.   Please review the URL below and make sure that it is spelled correctly.

Requested URL: /Tailored Blank/browsedir.asp

Klik om te vergroten...