Archief - Q: netwerk logger

ik ben op zoek naar een programmake da logt wie wat van mijn windows shares afhaalt/streamt.

ik heb windows vista btw ik had al ShareAlarm Pro geïnstalleerd, maar da werkt ni onder vista

iemand suggesties?

grtz,
bas

ik gebruik daarvoor deze batfile, schrijft de loggings in TXT fileke, heet sessionlog.bat en draai ik in een loop om realtime te monitoren:

@echo off
net file | find /i "Er staan geen gegevens in de lijst."
cls
if %ERRORLEVEL% EQU 0 set output=Y
if %ERRORLEVEL% EQU 1 set output=N

if %output%==Y goto end
if %output%==N goto execute

:execute
echo Het systeem logt nu welke gebruikers momenteel verbonden zijn via SMB.
time /t >> log.txt
date /t >> log.txt
echo Volgende sessies waren actief op het systeem... >> log.txt
net file >> log.txt
echo ------------------------------------------------------------------------------- >>log.txt
goto end

:end
call noblank.bat
IF EXIST *.out del *.out
echo Sluit de logging af met Control + C of met het kruisje...
call sessionlog.bat

waarbij noblank.bat de lege stukken uit de txt haalt om filespace te beperken:

:: noblank.bat
@echo off

for %%F in (log.txt) do call : sub1 %%F
goto :eof

: sub1

set outfile=%~n1.out
type nul > %outfile%
for /f "tokens=*" %%L in (%1) do (echo %%L>> %outfile%)
del *.txt
ren log.out log.txt
goto :eof
:: DONE

hij wilt ni... als ik het script run zegt hij: "systeemfout 5 ; toegang geweigerd"

bij mij nie
zijn dus wel twee batfiles, in dez. map zetten.

hebt wel enkel getest op XP en W2K3 mr zou ook moeten lukken , sff eens testen op vista

edit: zopas getest op vista: geen enkel probleem gehad

Hoe draait ge dat juist in een loopke?

Gewoon in een ander batfilleke der naar verwijzen ofzo?

het logt, maar het schrijft gewoon elke keer net list naar een file, en op een paar seconden heb ik al ne file van hier tot in tokyo... en hij moet netlist alleen logge wanneer er een verandering in komt

ik heb het probleem gevonden denk ik. De console heeft admin rights nodig, maar wanneer ik de batch file as admin run dan doet em alles maar 1 keer. Hoe kan ik dit oplossen?

een andere batch-file maken die deze loopt lijkt mij he makkelijkste

werkt ook ni... maar heb ondertussen het admin probleem opgelost, nu alleen nog zorgen dat da script alleen logt wanneer er een verandering komt in net file.... en da kan ik ni
en google verwijst naar deze pagina wanneer ik zoek op "net file" logger

gewoon

:1
echo whatever
goto 1

zo creëer je een loop ...
d4_ev1l: je hebt toch ook de noblank.bat in zelfde map gezet met volgende inhoud?

:: noblank.bat
@echo off

for %%F in (log.txt) do call : sub1 %%F
goto :eof

: sub1

set outfile=%~n1.out
type nul > %outfile%
for /f "tokens=*" %%L in (%1) do (echo %%L>> %outfile%)
del *.txt
ren log.out log.txt
goto :eof
:: DONE

inhoud van sessionlog.bat is dan weer:
@echo off
net file | find /i "Er staan geen gegevens in de lijst."
cls
if %ERRORLEVEL% EQU 0 set output=Y
if %ERRORLEVEL% EQU 1 set output=N

if %output%==Y goto end
if %output%==N goto execute

:execute
echo Het systeem logt nu welke gebruikers momenteel verbonden zijn via SMB.
time /t >> log.txt
date /t >> log.txt
echo Volgende sessies waren actief op het systeem... >> log.txt
net file >> log.txt
echo ------------------------------------------------------------------------------- >>log.txt
goto end

:end
call noblank.bat
IF EXIST *.out del *.out
echo Sluit de logging af met Control + C of met het kruisje...
call sessionlog.bat

waarbij de laatste regel "call sessionlog.bat" de loop oproept, Tizon

als je nog meer securitylogging wil doen, ik heb btw ook deze geschreven: logt de actuele VPN-connecties, de website, de gesharede files en de RDP-sessies op het systeem, zelfde principe:

@echo off
title Active Connection Logger - made by ShPonGle
echo Er wordt nu gelogd op gebruik van volgende protocollen en toepassingen:
echo VPN, SMB, RDP en HTTP
echo.

ipconfig | find /i "PPP-adapter" > NUL

if %ERRORLEVEL% EQU 0 set output=Y
if %ERRORLEVEL% EQU 1 set output=N
if %output%==Y goto vpngebruik
if %output%==N goto geenvpngebruik

:vpngebruik
FOR /F "tokens=1,2* delims=/\-." %%G in ('date /t') DO echo %%G-%%H-%%I >> D:\Logfiles\vpngebruik.txt
FOR /F "tokens=1,2* delims=/\-." %%G in ('time /t') DO echo %%G >> D:\Logfiles\vpngebruik.txt
echo. >> D:\Logfiles\vpngebruik.txt
echo. >> D:\Logfiles\vpngebruik.txt
echo Volgende users zijn via VPN ingelogd: >> D:\Logfiles\vpngebruik.txt
echo ------------------------------------- >> D:\Logfiles\vpngebruik.txt
netsh ras show client >> D:\Logfiles\vpngebruik.txt
goto control


:geenvpngebruik
FOR /F "tokens=1,2* delims=/\-." %%G in ('date /t') DO echo %%G-%%H-%%I >> D:\Logfiles\vpngebruik.txt
FOR /F "tokens=1,2* delims=/\-." %%G in ('time /t') DO echo %%G >> D:\Logfiles\vpngebruik.txt
echo. >> D:\Logfiles\vpngebruik.txt
echo. >> D:\Logfiles\vpngebruik.txt
echo De volgende users zijn via VPN ingelogd: >> D:\Logfiles\vpngebruik.txt
echo ---------------------------------------- >> D:\Logfiles\vpngebruik.txt
echo Behalve u is er niemand via vpn op het systeem ingelogd! >> D:\Logfiles\vpngebruik.txt
echo. >> D:\Logfiles\vpngebruik.txt
echo. >> D:\Logfiles\vpngebruik.txt
goto netfile

:control
netsh ras show client | find /i "Gebruiker" > NUL
if %ERRORLEVEL% EQU 0 set output=Y
if %ERRORLEVEL% EQU 1 set output=N
if %output%==Y goto vpneventcreate
if %output%==N goto restartras

:restartras
echo De RAS-service zit blijkbaar vast en wordt nu herstart...
net stop RemoteAccess
net start RemoteAccess
echo De RAS-service is hersteld van een probleem! >> D:\Logfiles\vpngebruik.txt
eventcreate /l system /so VPN-gebruik /t waarschuwing /id 5 /d "De RAS-service is hersteld van een probleem. De logfile is D:\Logfiles\vpngebruik.txt" > NUL
echo. >> D:\Logfiles\vpngebruik.txt
goto netfile

:vpneventcreate
eventcreate /l system /so VPN-gebruik /t waarschuwing /id 1 /d "Iemand is via vpn op het systeem aangelogd. De logfile is D:\Logfiles\vpngebruik.txt" > NUL
goto netfile

:netfile
FOR /F "tokens=1,2* delims=/\-." %%G in ('date /t') DO echo %%G-%%H-%%I >> D:\Logfiles\netfiles.txt
FOR /F "tokens=1,2* delims=/\-." %%G in ('time /t') DO echo %%G >> D:\Logfiles\netfiles.txt
echo. >> D:\Logfiles\netfiles.txt
echo. >> D:\Logfiles\netfiles.txt
echo Volgende users zitten op gedeelde mappen/bestanden: >> D:\Logfiles\netfiles.txt
echo --------------------------------------------------- >> D:\Logfiles\netfiles.txt
net file | find /i "lijst" > NUL
if %ERRORLEVEL% EQU 0 set output=N
if %ERRORLEVEL% EQU 1 set output=Y
if %output%==Y goto sharedviolation
if %output%==N goto noshare

: sharedviolation
net file >> D:\Logfiles\netfiles.txt
eventcreate /l system /so File-gebruik /t waarschuwing /id 2 /d "Er is iemand gedeelde bestanden aan het bekijken. De logfile is D:\Logfiles\netfiles.txt" > NUL
goto rdplog

:noshare
echo Er is niemand op gedeelde bestanden bezig. >> D:\Logfiles\netfiles.txt
echo. >> D:\Logfiles\netfiles.txt
goto rdplog

:rdplog
echo Volgende ip's zijn via remote desktop verbonden: >> D:\Logfiles\rdplogs.txt
echo ------------------------------------------------ >> D:\Logfiles\rdplogs.txt
echo. >> D:\Logfiles\rdplogs.txt
echo. >> D:\Logfiles\rdplogs.txt
goto rdpcheck

:rdpcheck
FOR /F "tokens=1,2* delims=/\-." %%G in ('date /t') DO echo %%G-%%H-%%I >> D:\Logfiles\rdplogs.txt
FOR /F "tokens=1,2* delims=/\-." %%G in ('time /t') DO echo %%G >> D:\Logfiles\rdplogs.txt
echo. >> D:\Logfiles\rdplogs.txt
echo. >> D:\Logfiles\rdplogs.txt
netstat | findstr "\<3389\>" > NUL

if %ERRORLEVEL% EQU 0 set output=Y
if %ERRORLEVEL% EQU 1 set output=N
if %output%==Y goto rdpeventlog
if %output%==N goto nobody

:rdpeventlog
netstat | findstr "\<3389\>" >> D:\Logfiles\rdplogs.txt
eventcreate /l system /so RDP-gebruik /t waarschuwing /id 3 /d "Iemand is via rdp op het systeem aangelogd. De logfile is D:\Logfiles\rdplogs.txt" > NUL
echo. >> D:\Logfiles\rdplogs.txt

goto websitecheck

:nobody
echo Er is niemand via rdp aangelogd! >> D:\Logfiles\rdplogs.txt
echo. >> D:\Logfiles\rdplogs.txt
echo. >> D:\Logfiles\rdplogs.txt
goto websitecheck

:websitecheck
FOR /F "tokens=1,2* delims=/\-." %%G in ('date /t') DO echo %%G-%%H-%%I >> D:\Logfiles\weblogs.txt
FOR /F "tokens=1,2* delims=/\-." %%G in ('time /t') DO echo %%G >> D:\Logfiles\weblogs.txt
echo. >> D:\Logfiles\weblogs.txt
echo. >> D:\Logfiles\weblogs.txt
echo Volgende ip's zijn met de website verbonden: >> D:\Logfiles\weblogs.txt
echo -------------------------------------------- >> D:\Logfiles\weblogs.txt
netstat | findstr "\<8100\>" > NUL
if %ERRORLEVEL% EQU 0 set output=Y
if %ERRORLEVEL% EQU 1 set output=N
if %output%==Y goto websitelog
if %output%==N goto noweblog

:websitelog
netstat | findstr "\<8100\>" >> D:\Logfiles\weblogs.txt
echo. >> D:\Logfiles\weblogs.txt
eventcreate /l system /so Website-bezoek /t waarschuwing /id 4 /d "Er is iemand is op de systeemwebsite aangelogd. De logfile is D:\Logfiles\weblogs.txt" > NUL
goto end

:noweblog
echo Er is niemand actief op de website! >> D:\Logfiles\weblogs.txt
echo. >> D:\Logfiles\weblogs.txt
goto end

:end
exit

wel oppassen met de absolute paden van mij en als je engelse windows hebt moet je paar woorden vertalen. schrijft in logfile + in de event viewer. ik draai deze via scheduled tasks elk uur op mn webserver, vind ik wel handig